積分(int)

単純な積分(int)

単純な不定積分.

> int(ln(x),x);	#res: x ln(x) - x

定積分を実行するには,積分変数の範囲を指定する.

> int(sin(x),x=-Pi..0);	#res: -2

特異点をもつ場合にも適切に積分結果を求めてくれる.

> int(1/sqrt(x*(2-x)),x=0..2); #res: pi

無限区間(infinity)における定積分も同様に計算してくれる.

> int(1/(x^2+4),x=-infinity..infinity); #res: 1/2 pi

部分積分法や置換積分法を用いる必要のある複雑な積分も一発で求まる.

> eq:=sqrt(4-x^2);int(eq,x);
$$ {\it eq}\, := \, \sqrt{4-{x}^{2}} \notag \\ \frac{1}{2}\,x \sqrt{4-{x}^{2}}+2\,\arcsin \left( 1/2\,x \right) \notag $$

数学の公式集に載っているような積分も同じコマンドで求まる.

> eq2:=exp(-x^2);int(eq2,x=0..zz);
$$ {\it eq2}\, := \,\exp({-{x}^{2}}) \notag \\ \frac{1}{2}\, \sqrt{\pi }\, \mbox{erf} \left(zz\right) \notag $$

studentパッケージいろいろ

ちょっとぐらい難しい積分も,Mapleは単純にintコマンドだけで実行してくれる.しかし,時には,途中の計算法である部分積分,置換積分,部分分数展開が必要になる.このような計算はstudentパッケージに用意さている.

> with(student):
部分積分(integration by parts)
> intparts(Int(x*exp(x),x),x);
$$ x\exp(x)-\int \exp(x){dx} $$
置換(change of variables)による積分
> Int((cos(x)+1)^3*sin(x), x);
> changevar(cos(x)+1=u, Int((cos(x)+1)^3*sin(x), x=a..b), u);
> changevar(cos(x)+1=u, int((cos(x)+1)^3*sin(x), x), u);
$$ \int \left( \cos \left( x \right) +1 \right) ^{3}\sin \left( x \right) {dx} \notag \\ \int _{\cos \left( a \right) +1}^{\cos \left( b \right) +1}-{u}^{3}{du} \notag \\ -\frac{1}{4}\,{u}^{4} \notag \\ $$
部分分数(partial fraction)展開による積分

部分分数(partial fraction)展開による積分では,convertコマンドを用いる.

> pf1:=convert(1/(1+x^3),parfrac,x);
  int(pf1,x);
$$ {\it pf1}\, := \frac{1}{3}\,{\frac {-x+2}{{x}^{2}-x+1}}+ \frac{1}{3\,\left( x+1 \right) } \notag \\ -\frac{1}{6}\,\ln \left( {x}^{2}-x+1 \right) +\frac{1}{3}\, \sqrt{3}\arctan \left( 1/3\, \left( 2\,x-1 \right) \sqrt{3} \right) +\frac{1}{3}\,\ln \left( x+1 \right) \notag $$
  1. 不定積分:次の不定積分を求めよ.

i) $\int 4\,x+3{dx}$ ,ii)$ \int \frac{1}{ 1+\mbox{e}^{x} }{dx}$ ,iii)$ \int \frac{1}{ \mbox{e}^{-x}+\mbox{e}^{x} }{dx}$ ,iv)$ \int \sqrt{1-{x}^{2}}{dx}$

  1. 定積分:次の定積分を求めよ.

i)$ \int _{0}^{\pi } \sin x{dx}$ ,ii)$ \int _{0}^{1} \arctan x{dx}$ ,iii)$ \int _{-2}^{2} \frac{1}{ \sqrt{4-{x}^{2}} }{dx}$ ,iv)$ \int _{0}^{1} \frac{1}{ {x}^{2}+x+1 }{dx}$

  1. (発展課題,重積分)次の2重積分を求めよ.
$$ \int \int_{D} \sqrt{x^2+y^2}dxdy\,\, D:0\leq y \leq x \leq 1 $$
> int(4*x+3,x);
> int( 1/(1+exp(x)),x);
> int(1/(exp(-x)+exp(x)),x);
> int(sqrt(1-x^2),x);
$$ 2\,{x}^{2}+3\,x \notag \\ -\ln \left( 1+ \mbox{e}^x \right) +\ln \left( \mbox{e}^x \right) \notag \\ \arctan \left( \mbox{e}^x \right) \notag \\ \frac{1}{2}\,x \sqrt{1-{x}^{2}}+\frac{1}{2}\,\arcsin \left( x \right) \notag $$
> int(sin(x),x=0..Pi);
> int(arctan(x),x=0..1);
> int(1/(sqrt(4-x^(2))),x=-2..2);
> int(1/(x^2+x+1),x=0..1);
$$ 2 \notag \\ \frac{1}{4}\,\pi -\frac{1}{2}\,\ln \left( 2 \right) \notag \\ \pi \notag \\ \frac{1}{9}\,\pi \, \sqrt{3} \notag $$
> with(plots):
> inequal({x-y>=0,x>=0,x<=1,y>=0},x=-0.5..1.5,y=-0.5..1.5,optionsexcluded=(color=white));
Intplot2d1.png
> f:=unapply(sqrt(x^2+y^2),(x,y)):
> plot3d(f(x,y),x=0..1,y=0..1,axes=box);
Intplot3d2.png
> int(int(f(x,y),y=0..x),x=0..1);
$$ \frac{1}{6} \sqrt{2}+\frac{1}{6}\,\ln \left( 1+ \sqrt{2} \right) $$
Last modified:2016/08/01 18:31:54
Keyword(s):
References:[MaplePrime] [MaplePrimeTOC] [SideMenu]